archrelease: copy trunk to community-staging-x86_64

git-svn-id: file:///srv/repos/svn-community/svn@533070 9fca08f4-af9d-4005-b8df-a31f2cc04f65

1 files changed, 46 insertions, 0 deletions

diff --git a/pandoc-crossref/repos/community-staging-x86_64/PKGBUILD b/pandoc-crossref/repos/community-staging-x86_64/PKGBUILD
new file mode 100644
index 00000000000..188ed916058
--- /dev/null
+++ b/pandoc-crossref/repos/community-staging-x86_64/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell@haskell.org>
+
+pkgname=pandoc-crossref
+pkgver=0.3.4.1
+pkgrel=126
+pkgdesc="Pandoc filter for cross-references"
+url="https://hackage.haskell.org/package/${pkgname}"
+license=("GPL2")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-data-default' 'haskell-data-accessor' 'haskell-data-accessor-template'
+         'haskell-data-accessor-transformers' 'haskell-gitrev' 'haskell-open-browser'
+         'haskell-optparse-applicative' 'pandoc' 'haskell-pandoc-types' 'haskell-roman-numerals'
+         'haskell-syb' 'haskell-utility-ht')
+makedepends=('ghc' 'haskell-hspec')
+conflicts=('haskell-pandoc-crossref')
+replaces=('haskell-pandoc-crossref')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/lierdakil/pandoc-crossref/archive/v$pkgver.tar.gz")
+sha512sums=('25cee0e9626e67d46769fff47da67fc616c1ce6c181e3c6e3f82b9dd1db1fc2bb3fe264da0e6c8d6082f8ea483530f88e917598ac9daaa2f6b97bbccca203254')
+
+build() {
+    cd $pkgname-$pkgver
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+	    -f-enable_flaky_tests
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}