archrelease: copy trunk to community-staging-x86_64

git-svn-id: file:///srv/repos/svn-community/svn@533059 9fca08f4-af9d-4005-b8df-a31f2cc04f65

1 files changed, 43 insertions, 0 deletions

diff --git a/haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD b/haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD
new file mode 100644
index 00000000000..1c0d994c7d1
--- /dev/null
+++ b/haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars@archlinux.org>
+
+_hkgname=skylighting-core
+pkgname=haskell-skylighting-core
+pkgver=0.8.2.3
+pkgrel=1
+pkgdesc="Syntax highlighting library"
+url="https://github.com/jgm/skylighting"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-attoparsec'
+         'haskell-base64-bytestring' 'haskell-blaze-html' 'haskell-case-insensitive'
+         'haskell-colour' 'haskell-hxt' 'haskell-regex-pcre' 'haskell-safe'
+         'haskell-utf8-string')
+makedepends=('ghc' 'haskell-diff' 'haskell-hunit' 'haskell-pretty-show' 'haskell-quickcheck'
+             'haskell-random' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('512814356ce23673a75dd639946e8d0ae19fc47d96d7611bb0f66638d3256d6a1b01f7f7cfc6ad00e658392106bfbb39a69e2c298bfa891cded7e6baa6dd1984')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fexecutable -fsystem-pcre
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}