archrelease: copy trunk to testing-x86_64

git-svn-id: file:///srv/repos/svn-packages/svn@369677 eb2447ed-0c53-47e4-bac8-5bc4a241df78

1 files changed, 42 insertions, 0 deletions

diff --git a/nvidia-lts/repos/testing-x86_64/PKGBUILD b/nvidia-lts/repos/testing-x86_64/PKGBUILD
new file mode 100644
index 00000000000..1deda38e54d
--- /dev/null
+++ b/nvidia-lts/repos/testing-x86_64/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
+# Maintainer: Eric Bélanger <eric@archlinux.org>
+
+pkgname=nvidia-lts
+pkgver=440.36
+pkgrel=1
+epoch=1
+pkgdesc="NVIDIA drivers for linux-lts"
+arch=('x86_64')
+url="https://www.nvidia.com/"
+makedepends=("nvidia-utils=${pkgver}" 'libglvnd' 'linux-lts-headers')
+provides=('nvidia')
+license=('custom')
+options=('!strip')
+_pkg="NVIDIA-Linux-x86_64-${pkgver}"
+source=("https://us.download.nvidia.com/XFree86/Linux-x86_64/${pkgver}/${_pkg}.run")
+sha512sums=('445d7f58de418cbee79895469a27afa2186656a961499dfc0e7e62ba1f773f5a011affa563b0fc50c212b9e06b23f63e182c122b36d0d93c39cc3e9ff3641410')
+
+prepare() {
+    sh "${_pkg}.run" --extract-only
+    cd "${_pkg}"
+}
+
+build() {
+    cd "${_pkg}"/kernel
+    make SYSSRC=/usr/src/linux-lts module
+}
+
+package() {
+    depends=('linux-lts' "nvidia-utils=${pkgver}" 'libglvnd')
+
+    _extradir="/usr/lib/modules/$(</usr/src/linux-lts/version)/extramodules"
+    install -Dt "${pkgdir}${_extradir}" -m644 \
+      "${srcdir}/${_pkg}/kernel"/nvidia{,-modeset,-drm,-uvm}.ko
+
+    find "${pkgdir}" -name '*.ko' -exec gzip -n {} +
+
+    echo "blacklist nouveau" |
+        install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
+
+    install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m644 "${srcdir}/${_pkg}/LICENSE"
+}